Don't assign when you want an empty list.

Item 3: Don't assign undef when you want an empty list.

Uninitialized scalar variables in Perl have the value undef. You can reset scalar variables to their "pristine" state by assigning undef to them, or by using the undef operator:

$toast = undef;

undef $history;

Uninitialized array variables, however, have the value (), the empty list. If you assign undef to an array variable, what you actually get is a list of one element containing undef:

Don't assign undef to an array variable.

@still_going = undef;

if (@still_going) { ... }

The simplest way to avoid this is to assign the empty list () to array variables when you want to clear them. You can also use the undef verb:

@going_gone = (); 
if (@going_gone) { ... }

undef @going_gone; 
if (defined(@going_gone)) { ... }

The defined operator is the only way to distinguish undef from 0 and the empty string ''. The defined operator will work on any value—in earlier versions of Perl it would work only on lvalues, but that is no longer the case.

if (defined($a)) { ... } 
if (defined(0)) { ... }

if (defined(@a)) { ... } 
if (defined(())) { ... }

You can assign undef to an element of an array:

$puka[3] = undef; 
@puka[1, 5, 7] = (); 
@puka[0..99] = ();

Note that undef is a perfectly reasonable element value. You cannot shorten an array by assigning undef values to elements at the end of the array. To actually shorten an array without assigning a whole new value to it, you must assign to $#array_name or use one of the array operators like splice or pop.

@a = 1 .. 10; 
$a[9] = undef; 
print scalar(@a), "\n";

$val = pop @a; 
print scalar(@a), "\n";

splice @a, -2; 
print scalar(@a), "\n";

$#a = 4; 
print scalar(@a), "\n";

Hashes and undef

The remarks above also apply to hashes. As with arrays, you cannot undef a hash by assigning undef to it. In fact, assigning any list with an odd number of elements to a hash results in a warning message (at least in newer versions of Perl). You can assign the empty list () to create an empty hash, or you can use the undef operator to reset the hash to a pristine state.

%gone = (); 
if (keys %gone) { ... }

%nuked = (U => '235', Pu => 238); 
undef %nuked; 
if (keys %nuked) { ... } 
if (defined %nuked) { ... }

As with arrays, you cannot shorten or remove elements from a hash by assigning undef values to them. In order to remove elements from a hash you must use the delete operator. The delete operator can be used on hash slices as well as single elements:

Use delete to remove key-value pairs from hashes.

%spacers = ( 
  husband => "george", wife => "jane", 
  daughter => "judy", son => "elroy" 
);

delete $spacers{'husband'}; 
if (exists $spacers{'husband'}) { ... }

delete @spacers{'daughter', 'son'};